Arduino Digital Clock: DS3231 RTC and OLED Display

In this project, you’ll learn how to create a digital clock with the Arduino using the DS3231 Real Time Clock (RTC) module and an OLED display. We’ll provide you with all the required steps, including the circuit diagram, code, and an explanation of the code.

Arduino Digital Clock with DS3231 RTC and OLED Display

Recommended resources:

To better understand the steps to build the digital clock, we recommend that you get familiar with the DS3231 RTC module and the OLED display, by taking a look at the following guides:

Project Overview

Arduino Clock with DS3231 and OLED Display

This project is quite simple to understand:

We first set the time of the DS3231 Real Time Clock module;
Then, we get the date, time, and temperature from the RTC;
We display the date, time, and temperature on the OLED display;
We refresh the OLED with the new current time and readings every second.

Parts Required

Here’s a list of the parts required for this project:

Arduino UNO (or other Arduino board) – read Best Arduino Starter Kits
DS3231 Module
SSD1306 I2C OLED Display
Jumper wires
Breadboard

You can use the preceding links or go directly to MakerAdvisor.com/tools to find all the parts for your projects at the best price!

Wiring the Circuit

Follow the next schematic diagram to wire the circuit, or use the following table as a reference. Both modules communicate with the Arduino board using I2C communication protocol.

Since each module has a unique I2C address, we can use the same I2C bus (same I2C pins) to establish a communication between the Arduino and the modules.

OLED Display	DS3231 RTC	Arduino
GND	GND	GND
VCC	VCC	5V
SCL	SCL	A5
SDA	SDA	A4
	SQW	Don’t connect
	32K	Don’t connect

Arduino digital clock ds3231 and oled display - schematic diagram

Installing Libraries

For this tutorial, you need to install the following libraries:

Follow the next instructions to install the libraries:

In the Arduino IDE, go to Sketch > Include Library > Manage Libraries. Search for RTCLib and install the library by Adafruit. We’re using version 2.1.4.

Then, search for Adafruit SSD1306 and install the library.

Now you have installed all the required libraries for this project.

Arduino Digital Clock – Code

The following code creates the digital clock. Copy to your Arduino IDE and upload it to your board.

/*********
  Rui Santos & Sara Santos - Random Nerd Tutorials
  Complete instructions at https://RandomNerdTutorials.com/arduino-digital-clock-ds3231-oled/
*********/

#include <Wire.h>
#include <RTClib.h>
#include <Adafruit_SSD1306.h>

RTC_DS3231 rtc;

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

// Create OLED object
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

// Days of the week array
char daysOfTheWeek[7][12] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

void setup() {
  Serial.begin(9600);

  // Initialize OLED display
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println("SSD1306 allocation failed");
    for (;;);
  }

  // Clear the display
  display.clearDisplay();
  display.display();

  // Initialize RTC
  if (!rtc.begin()) {
    Serial.println("Couldn't find RTC");
    while (1);
  }

  // Check if RTC lost power and set the time if necessary
  if (rtc.lostPower()) {
    Serial.println("RTC lost power! Setting the time...");
    // Set the RTC to the date & time this sketch was compiled
    rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
  }
  // Or, if you need to set the time for the first time, uncomment the following line:
  // rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));

}

void loop() {
  // Get the current time from the RTC
  DateTime now = rtc.now();

  // Clear the OLED display buffer
  display.clearDisplay();

  // Display the date
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 0);
  display.print("Date: ");
  display.print(now.year());
  display.print("-");
  if (now.month() < 10) display.print("0");
  display.print(now.month());
  display.print("-");
  if (now.day() < 10) display.print("0");
  display.print(now.day());

  // Display the time
  display.setCursor(0, 15);
  display.print("Time: ");
  if (now.hour() < 10) display.print("0");
  display.print(now.hour());
  display.print(":");
  if (now.minute() < 10) display.print("0");
  display.print(now.minute());
  display.print(":");
  if (now.second() < 10) display.print("0");
  display.print(now.second());

  // Display the day of the week
  display.setCursor(0, 30);
  display.print("Day: ");
  display.print(daysOfTheWeek[now.dayOfTheWeek()]);

  // Display the temperature from DS3231
  display.setCursor(0, 45);
  display.print("Temp: ");
  display.print(rtc.getTemperature());
  display.cp437(true);
  display.write(167);
  display.print("C");

  // Display everything on the OLED
  display.display();

  delay(1000);
}

View raw code

How Does the Code Work

Let’s take a quick look at how the code works.

First, include the required libraries. The Wire for I2C communication protocol, the RTCLib to interface with the DS3231, and the Adafruit_SSD1306 to interface with the OLED.

#include <Wire.h>
#include <RTClib.h>
#include <Adafruit_SSD1306.h>

Create an RTC_DS3231 instance called rtc to refer to the RTC module.

RTC_DS3231 rtc;

Define the OLED screen width and height.

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

Create an Adafruit_SSD1306 called display with the screen width and height defined earlier.

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

Then, you create a char array with the days of the week.

char daysOfTheWeek[7][12] = {"Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"};

You can access each day by its index. For example:

daysOfTheWeek[0] will return “Sunday”.
daysOfTheWeek[1] will return “Monday”.

In the setup(), the following lines will initialize the OLED display.

// Initialize OLED display
if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
  Serial.println("SSD1306 allocation failed");
  for (;;);
}

These two commands will clear the display.

display.clearDisplay();
display.display();

Next, we intiailzie the RTC module.

// Initialize RTC
if (!rtc.begin()) {
  Serial.println("Couldn't find RTC");
  while (1);
}

Then, check if the RTC has lost power with the lostPower() function. If it is not running, because it is a new device or because the battery backup failed, we’ll print a message in the Serial Monitor and set the time.

if (rtc.lostPower()) {
  Serial.println("RTC lost power, let's set the time!");

Setting the Time

To set the time on the RTC, we can use the adjust() method on our rtc object. The following line sets the RTC’s date and time to the current date and time when this sketch was last compiled.

rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));

__DATE__ and __TIME__ are macros that provide the current date and time at compilation.

If you need to re-set the time on a previously configured device, you can uncomment the following line.

// rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));

In the loop(), we get data from the RTC module as follows.

DateTime now = rtc.now();

It returns a DateTime object containing the values for the current year, month, day, hour, minute, and second.

To access each field of the date and time, we can use the following methods:

now.year()	Gets the current year (e.g., 2024)
now.month()	Gets the current month (1–12)
now.day()	Gets the current day of the month (1–31)
now.dayOfTheWeek()	Gets the day of the week (0-6), where 0 is Sunday, and 6 is Saturday
now.hour()	Gets the current hour (0–23)
now.minute()	Gets the current minute (0–59)
now.second()	Gets the current second (0–59)

We set the display text size and color.

display.setTextSize(1);
display.setTextColor(WHITE);

And then, we start displaying the information on the display. The following lines display the date.

display.setCursor(0, 0);
display.print("Date: ");
display.print(now.year());
display.print("-");
if (now.month() < 10) display.print("0");
display.print(now.month());
display.print("-");
if (now.day() < 10) display.print("0");
display.print(now.day());

Next, we display the time:

display.setCursor(0, 15);
display.print("Time: ");
if (now.hour() < 10) display.print("0");
display.print(now.hour());
display.print(":");
if (now.minute() < 10) display.print("0");
display.print(now.minute());
display.print(":");
if (now.second() < 10) display.print("0");
display.print(now.second());

The day of the week:

display.setCursor(0, 30);
display.print("Day: ");
display.print(daysOfTheWeek[now.dayOfTheWeek()]);

And finally, the temperature.

display.setCursor(0, 45);
display.print("Temp: ");
display.print(rtc.getTemperature());
display.cp437(true);
display.write(167);
display.print("C");

To display the º symbol, we use the Code Page 437 font. For that, you need to set the cp437 to true as follows:

display.cp437(true);

Then, use the write() method to display your chosen character. The º symbol corresponds to character 167.

display.write(167);

Finally, you need to call display.display() so that the information is actually written on the screen.

display.display();

Note that we add a leading zero when the number is smaller than 10 on the time and date. So, instead of having, for example: 3:5:6 (which is weird for a time format), you’ll get 03:05:06.

Demonstration

Upload the code to your Arduino board. Make sure you select the right board and COM port on the Arduino IDE.

After uploading, the OLED display will show the date, time, and temperature. The data is updated every second.

Arduino Digital DS3231 Digital Clock and OLED Display

Wrapping Up

Congratulations! You’ve built a digital clock with the Arduino, the DS3231 RTC module, and the OLED display. Instead of an OLED display, you may want to use an LCD instead.

We have other projects with the Arduino that you may like:

Learn more about the Arduino with our resources: