How to Set an ESP32 Access Point (AP) for Web Server

The ESP32 can act as a Wi-Fi station, as an access point, or both. In this tutorial we’ll show you how to set the ESP32 as an access point using Arduino IDE.

In most projects with the ESP32, we connect the ESP32 to a wireless router (see our ESP32 web server tutorial). This way we can access the ESP32 through the local network.

In this situation the router acts as an access point and the ESP32 is set as a station. In this scenario, you need to be connected to your router (local network) to control the ESP32.

But if you set the ESP32 as an access point (hotspot), you can be connected to the ESP32 using any device with Wi-Fi capabilities without the need to connect to your router.

In simple words, when you set the ESP32 as an access point you create its own Wi-Fi network and nearby Wi-Fi devices (stations) can connect to it (like your smartphone or your computer).

Here we’ll show you how to set the ESP32 as an access point in your web server projects. This way, you don’t need to be connected to a router to control your ESP32. Because the ESP32 doesn’t connect further to a wired network (like your router), it is called soft-AP (soft Access Point).

Installing the ESP32 board in Arduino IDE

There’s an add-on for the Arduino IDE that allows you to program the ESP32 using the Arduino IDE and its programming language. Follow one of the following tutorials to prepare your Arduino IDE:

ESP32 Access Point

In this example, we’ll modify an ESP32 Web Server from a previous tutorial to add access point capabilities. What we’ll show you here can be used with any ESP32 web server example.

Upload the sketch provided below to set the ESP32 as an access point.

/*********
  Rui Santos
  Complete project details at https://randomnerdtutorials.com  
*********/

// Load Wi-Fi library
#include <WiFi.h>

// Replace with your network credentials
const char* ssid     = "ESP32-Access-Point";
const char* password = "123456789";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output26State = "off";
String output27State = "off";

// Assign output variables to GPIO pins
const int output26 = 26;
const int output27 = 27;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output26, OUTPUT);
  pinMode(output27, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output26, LOW);
  digitalWrite(output27, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Setting AP (Access Point)…");
  // Remove the password parameter, if you want the AP (Access Point) to be open
  WiFi.softAP(ssid, password);

  IPAddress IP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(IP);
  
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /26/on") >= 0) {
              Serial.println("GPIO 26 on");
              output26State = "on";
              digitalWrite(output26, HIGH);
            } else if (header.indexOf("GET /26/off") >= 0) {
              Serial.println("GPIO 26 off");
              output26State = "off";
              digitalWrite(output26, LOW);
            } else if (header.indexOf("GET /27/on") >= 0) {
              Serial.println("GPIO 27 on");
              output27State = "on";
              digitalWrite(output27, HIGH);
            } else if (header.indexOf("GET /27/off") >= 0) {
              Serial.println("GPIO 27 off");
              output27State = "off";
              digitalWrite(output27, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #555555;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP32 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 26  
            client.println("<p>GPIO 26 - State " + output26State + "</p>");
            // If the output26State is off, it displays the ON button       
            if (output26State=="off") {
              client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 27  
            client.println("<p>GPIO 27 - State " + output27State + "</p>");
            // If the output27State is off, it displays the ON button       
            if (output27State=="off") {
              client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

View raw code

Customize the SSID and Password

You need to define a SSID name and a password to access the ESP32. In this example we’re setting the ESP32 SSID name to ESP32-Access-Point, but you can modify the name to whatever you want. The password is 123456789, but you can also modify it.

// You can customize the SSID name and change the password
const char* ssid = "ESP32-Access-Point";
const char* password = "123456789";

Setting the ESP32 as an Access Point

There’s a section in the setup() to set the ESP32 as an access point using the softAP() method:

WiFi.softAP(ssid, password);

There are also other optional parameters you can pass to the softAP() method. Here’s all the parameters:

.softAP(const char* ssid, const char* password, int channel, int ssid_hidden, int max_connection)
  • SSID (defined earlier): maximum of 63 characters;
  • password(defined earlier): minimum of 8 characters; set to NULL if you want the access point to be open
  • channel: Wi-Fi channel number (1-13)
  • ssid_hidden: (0 = broadcast SSID, 1 = hide SSID)
  • max_connection: maximum simultaneous connected clients (1-4)

Next, we need to get the access point IP address using the softAPIP() method and print it in the Serial Monitor.

IPAddress IP = WiFi.softAPIP();
Serial.print("AP IP address: ");
Serial.println(IP);

These are the snippets of code you need to include in your web server sketches to set the ESP32 as an access point. To learn how the full web server code works, take a look at the ESP32 Web Server tutorial.

Parts Required

For this tutorial you’ll need the following parts:

You can use the preceding links or go directly to MakerAdvisor.com/tools to find all the parts for your projects at the best price!

Schematic

Start by building the circuit. Connect two LEDs to the ESP32 as shown in the following schematic diagram – one LED connected to GPIO 26, and the other to GPIO 27.

Note: We’re using the ESP32 DEVKIT DOIT board with 36 pins. Before assembling the circuit, make sure you check the pinout for the board you’re using.

ESP32 IP Address

Upload the code to your ESP32 (make sure you have the right board and COM port selected). Open the Serial Monitor at a baud rate of 115200. Press the ESP32 “Enable” button.

The IP address you need to access the ESP32 point will be printed. In this case, it is 192.168.4.1.

Connecting to the ESP32 Access Point

Having the ESP32 running the new sketch, in your smartphone open your Wi-Fi settings and tap the ESP32-Access-Point network:

Enter the password you’ve defined earlier in the code.

Open your web browser and type the IP address 192.168.4.1. The web server page should load:

To connect to the access point on your computer, go to the Network and Internet Settings and select the “ESP32-Access-Point“.

Insert the password you’ve defined earlier.

And it’s done! Now, to access the ESP32 web server page, you just need to type the ESP32 IP address on your browser.

Wrapping Up

This simple tutorial showed you how to set the ESP32 as an access point on your web server sketches. When the ESP32 is set as an access point, devices with Wi-Fi capabilities can connect directly to the ESP32 without the need to connect to a router.

You may also like reading:

We hope you’ve found this tutorial useful. If you like ESP32 and you want to learn more, we recommend enrolling in Learn ESP32 with Arduino IDE course.

Thanks for reading.



Learn how to program and build projects with the ESP32 and ESP8266 using MicroPython firmware DOWNLOAD »

Learn how to program and build projects with the ESP32 and ESP8266 using MicroPython firmware DOWNLOAD »


Enjoyed this project? Stay updated by subscribing our weekly newsletter!

62 thoughts on “How to Set an ESP32 Access Point (AP) for Web Server”

  1. Hi Sara hi Rui,
    Thank you very much for your last posts about esp32.
    I’m a bit lost in “Wifi libraries”.
    My question : For Arduino, Esp8266 or ESP32, is it the same wifi.h library ?
    I tried to find an answer in you different posts but it seems not to be precisely indicated.
    Best regards

    Reply
    • Hi Gabriel.
      With the ESP32 and Arduino we use the WiFi.h library. However, those libraries are different for the ESP32 and ESP8266. If you’re having trouble compiling ESP32 code that uses the WiFi.h library, you must remove the Arduino WiFi library from your Arduino IDE installation.
      The ESP8266 uses the ESP8266WiFi.h library.
      Regards,
      Sara 🙂

      Reply
  2. It’s the “max_connection” limitation of. “1-4” that puts this outside the range of being really useful.

    The Raspberry Pi will get to about 30 and then begin throttling back.

    For just a home Website, it might be useful, I suppose.

    Reply
  3. Ciao, e complimenti per l’articolo che trovo particolarmente interessante.
    Ho modificato il codice adattandolo a una scheda diversa, e più precisamente NodeMcu Lolin V.3, ma quando cerco di caricare il codice mi dà questo errore. Mi aiuteresti a capire il problema?

    Hello, and congratulations for the article that I find particularly interesting.
    I modified the code by adapting it to a different card, and more specifically NodeMcu Lolin V.3, but when I try to load the code it gives me this error. Would you help me to understand the problem?

    C:\Users\miche\Documents\Arduino\Rui_Santos_AP_Server_Modificato\Rui_Santos_AP_Server_Modificato.ino: In function ‘void setup()’:

    Rui_Santos_AP_Server_Modificato:44: error: ‘class WiFiClass’ has no member named ‘softAP’

    WiFi.softAP(ssid, password);

    ^

    Rui_Santos_AP_Server_Modificato:46: error: ‘class WiFiClass’ has no member named ‘softAP’

    IPAddress IP = WiFi.softAP();

    ^

    Uso la libreria WiFi alla versione 1.2.7 nella cartella: C:\Program Files\WindowsApps\ArduinoLLC.ArduinoIDE_1.8.10.0_x86__mdqgnx93n4wtt\libraries\WiFi
    Uso la libreria SPI alla versione 1.0 nella cartella: C:\Users\miche\Documents\ArduinoData\packages\esp8266\hardware\esp8266\2.4.0\libraries\SPI
    exit status 1
    ‘class WiFiClass’ has no member named ‘softAP’

    Reply
      • Ciao, e grazie per la risposta.
        Ieri ho aggiornato il mio IDE e installato il componente aggiuntivo ESP32, ma sembra di capire che le librerie vengono richiamate automaticamente dal codice in base alla scheda selezionata, e la mia scheda non è un ESP32 ma una NodeMcu (8266, giusto?) forse il problema è la scheda. Lo sketch è ottimizzato per ESP32 ma la mia scheda non lo è. Chiedo se altri hanno avuto il mio stesso problema, e se lo hanno risolto, magari modificando il codice.

        Hello and thanks for the reply. Yesterday I updated my IDE and installed the ESP32 add-on, but it seems to understand that the libraries are automatically recalled by the code according to the selected card, and my card is not an ESP32 but a NodeMcu (8266, right?) Maybe the problem is the card. The sketch is optimized for ESP32 but my card is not. I ask if others have had the same problem, and if they have solved it, maybe by changing the code.

        Reply
  4. Ciao Sara, grazie infinite. È come temevo, il codice qui descritto non va bene per la mia scheda.
    Appena posso uso il codice da te indicato e ti faccio sapere.
    Grazie ancora, a presto.

    Reply
    • Good luck with your project! I hope you make it work.
      P.S. Next time, try to post your questions in english, so that everyone is able to understand.
      Thanks.
      Regards,
      Sara 🙂

      Reply
  5. Hello Sara, I just wanted to apologize to you and everyone in the forum for posting my last questions in my mother tongue rather than in English. Unfortunately for my distraction I did not think to do the translation before publishing them.
    I hope I did not create inconvenience to those who followed these posts.
    Thank you again for your availability, I offer my regards.
    Michele

    Reply
    • Hi.
      You have to insert the following lines in your code to give your ESP32 network a name, and a password. It can be whatever you want.
      const char* ssid = “ESP32-Access-Point”;
      const char* password = “123456789”;
      Then, set the access point with the following line:
      WiFi.softAP(ssid, password);
      And get the IP address with the following:
      IPAddress IP = WiFi.softAPIP();
      Serial.print(“AP IP address: “);
      Serial.println(IP);
      Everything is explained in the tutorial.
      Regards,
      Sara 🙂

      Reply
  6. Hi guys, just want to say a great tutorial. I have a Heltec ESP32 with OLED display and have the web server up and running in both AP and STA modes. Works like a treat. I have the OLED display the text status of 3 of the output pins (one of which is the on-board LED Pin25).
    I have added a third button which was very easy. Also changed the size & colour of the buttons.
    Great stuff!!

    Reply
    • Hi Musi,
      When the ESP32 is set as an access point, when you connect your smartphone to the ESP32, you are connected to the ESP32 network.
      So, you can’t access apps that require data network.
      Regards,
      Sara 🙂

      Reply
  7. Thank your for a very thorough tutorial.
    I am having problems getting it to work on IOS devices. I works fine on Win 10 and Android devices. If I try to connect with a IOS 12 phone it wont connect and in the device ip address it does not list the expected 192.168.4.1 address. If I modify the source code to not pass the password parameter. IE an open network it connects as expected. I have tried similar examples from other sites and they produce similar results.
    I would be grateful if you could give me any help as how to proceed with debugging the problem. I am using esp32 and using the code you supply.

    Reply
    • Hi Chris.
      That’s very weird and I have no idea why that is happening.
      It may be something related with your phone.
      Other people reported issues about connecting with other phones, but I don’t know what the reason is.
      I’ve searched on the internet and haven’t found a clear answer.
      I found this issue on the forum, but it doesn’t have an answer yet: github.com/espressif/arduino-esp32/issues/2242
      It is a problem similar to yours.
      Sorry that I can’t help much.
      Regards,
      Sara

      Reply
      • My understanding (which could be wrong) is that iOS, and some other phones, won’t connect unless there is an onward connection to the Internet.

        This has caused me unresolved problems with Raspberry Pi based devices.

        Reply
  8. Thanks any way for taking the time to reply. It seems it may be a problem with IOS rather than the ESP side of things. If I find an answer I will let you know 🙂

    Thanks again for a very informative site.

    Regards from Chris.

    Reply
  9. Greetings;

    I’m still understanding the code and procedures.
    1 Question: Is it possible to configure Wifi Encryption?

    Something like:

    byte encryption = 2;

    TKIP (WPA) = 2
    // WEP = 5
    // CCMP (WPA) = 4
    // NONE = 7
    // AUTO = 8

    Both WiFi and WiFiAp classes dont have a way to set this; but I’ve read that it is possible.
    Thanks in advance.

    Reply
  10. Hi Sara, thanks for all your tutorials on this website, they are very clear and well done!

    After setting my ESP32 as an access point, can I send data from this one?
    I mean I’d like to send the data from a sensor connected to my ESP32 and reading them on my phone or tablet.

    Thanks.

    Bryan

    Reply
    • Hi Bryan.
      Yes, you can do that. It works like any other web server we have in our tutorials. But instead of connecting to your local network to get the readings, you connect to the ESP32 access point.
      Regards,
      Sara

      Reply
  11. O was trying to set an esp32 cam as an access point, so i could see the vídeo stream, with no need to connect to the router…but no luck yet…maybe you guys could lend a hand😉

    Reply
      • Well..the main problem are my poor programing skills…😣
        Appart from that i’m trying to make a sort of a standalone WiFi câmera on the cheap…that you could hide in common everyday objects…and that could be accessed on and Android phone..wich could store the stream if wanted..
        .it seems a good project for the esp32 and android app development…
        Are you interested in helping

        Reply
  12. It is known that max_connection” limitations is 4 for ESP8266 and 32
    Also is known that for 8266 can be extend to 8 and for 32 even more
    Can you help me for doing this

    Regards

    Reply
  13. You say that ” there are also other optional parameters you can pass to the softAP() method. Here’s all the parameters:”
    max_connection: maximum simultaneous connected clients (1-4)
    Haw to program softAP to accept 8 or more simultaneous connected clients
    Will be very useful if you will make a tutorial or help me to do that.
    Best regards

    Reply
  14. Ok, so I’m a little bit behind (Ha!)….but, none the less, this is a great project!

    This morning I put it together with a DS18B20, added a 3rd button to the webpage and temperature readout. VERY COOL!

    Hopefully I can add a Si7021 on I2C and display that as well in the near future. This saves so much other work! All I need to do is drop my solar battery to a 5V level with a switching module, hook it up to the dev board, and bam! remote access, monitoring, and control! Wow!

    I LOVE RNT!!!

    Thanks so much for your projects and inspirations!
    Best Always!
    Dave

    Reply
  15. I’m searching for a way to send “time” to 6 stations mostly ESP-01s (I may use other board if useful ) from a server like ESP32. Not using my local network nor using the net. Just to send the time to all the stations at the same time. Not need to receive any data from those stations. Do you have a good direction on how to do it. What I see on the net is always the reverse like Stations sending to the Server. I don’t want to use UDP as it’s not safe. Many thanks for your help. 02-15-2020

    Reply
      • Hey!!! that’s what I need, finally. And If I may, my optimal setup would be to use all ESP-01s with a Pic from microchip as all my thermostat setup is almost done with PIC. And if possible in a near future I may need to access my local network to change some settings in the master thermostat using my computer, but without being able to go on the net for safety reasons. So if you can give us some details on how to do it I’m sure that it will be useful to others.
        Thanks for your help.

        Reply
  16. I really like this tutorial, but I am having a problem with it. Everything is going well until I disconnect the wifi from my pc and try to reconnect, then my page breake and cannot reconnect. It’s a big problem for code applications, since i can’t get very far from the project after I start running the code without losing my connection. I can’t be reseting the Esp32 fisicaly, and the only way i find to repair it, is rebooting. I’m not a professional programmer and, unfortunately, I still haven’t found a solution for that. If anyone knows how to enable it can be connected and disconnected from wifi without problems, please help me. I’m already happy for the post, but this help can make it even more interesting. thanks

    Reply
  17. Hello Rui & Sara
    Thanks – great work
    I cannot get soft AP mode to work with the RTOS, do you know any reason for this ?

    Thanks Hb

    Reply
  18. Great tutorial as always.
    Is there a way of using Soft Access Point with ESP32 Cam, to stream video from ESP32 Cam to Phone/tablet without using Router?

    Reply
  19. Hi Rui and Sara.
    Perhaps this is a network concept rather than a esp32 concept, but i think thath you could help me…
    If the ESP32 is the Acces Point, i’m able to connect my laptop to its own network , right?
    And usign its own network can i acces to any web page like it was the normal router network? How is it possible?
    I understand that the router is connected by wire to the global network, for this reason when i connect a device to the router wifi i can go to any web page of the world.
    Instead, how the information of any web page can arrive to my laptop through the ESP32 network, if this ESP32 is not connected to the global network?

    It is more a conceptual doubt than a software/hardware doubt.

    I’m looking forward to hearing from you!

    Reply
    • You have misunderstood.

      You would be able to access a webpage that is hosted on the ESP-32 only – you would not have access to webpages on the Internet.

      It can be useful to have a locally hosted webpage to supply specific information. If you have regular visitors, for instance, you could have the webpage show local buildings of interest and their history, things like that.

      Reply
  20. Hi, a bit late to the party I know. I found your article very helpful and very informative to a
    serious newbie at this programming stuff.
    Using your code got me running an esp32-cam as an access point and with a simple aerial I can get ~200m which is perfect for my needs.
    I would like to use multiple cameras each with their own SSID and IP address, the SSID is obvious but I have no idea how to get a different IP on each camera AP.

    Can anyone point me in the right direction?

    Reply
  21. Sara,
    Thanks so much for the prompt reply,
    Your static IP tutorial sets a fixed IP address to the esp32 when connecting to, say, my home network 192.168.1.xxx, what I need is to be able to control the IP address that the esp32 issues (DHCP), when acting as an access point, in the one I have done so far from your tutorial, 192.168.4.1. I intend to have six cameras close to one another and need to be able to connect to any of then individually.
    It occurs to me that the SSID might perform this function in a way, all cameras being on a separate network?

    Thanks again Graham

    Reply
    • Hi.
      Yes, because they are on a different network, you can connect to them separately.
      They will all have the 192.168.4.1 address, but because they are on different networks, you can connect to them separately.
      Regards,
      Sara

      Reply
  22. I have the soft AP server running on an ESP32_CAM with a battery, a 3.3V regulator and an external antenna. It works fine when the serial cable is attached but stops updating images when it is removed.

    If I touch the serial port pins with my hand, it starts again and stops as soon as I remove my hand.. Touching other pins on side of the ESP32 CAM board with the serial port also keeps it running. Touching pins on the other edge of the board does not appear to have this effect. Any thoughts on this mystery?

    Thanks,

    Bob

    Reply
      • Sara,

        I did send an update to Rui but I’ll post it here along with some added info.
        I submitted a post yesterday about intermittent operation of the
        ESP32-CAM that involved touching the serial port pins to get it working.

        The problem appears to be fixed but you might want to remember this
        for future reference given that you are the repository for all things ESP32.

        I had glued the external antenna to the end of the ESP32-CAM along the edge with the internal antenna and experienced the problems.

        Breaking the glue joint and moving the antenna a small distance away
        from the ESP32_CAM fixed the problem. . I further experimented and could get occasional image updates depending on where I placed my hands near the antenna.

        My assumption is that RF energy from the WiFi antenna was getting picked up and upsetting the operation but not crashing the system since it always resumed working when I touched the pins.

        Now here is where it gets (more) interesting. I popped an ESP32-CAM with internal antenna into my test fixture and saw exactly the same problem except that I couldn’t move the antenna away as it was built-in.

        Next I put a .1uF capacitor between the 3.3V pin and the nearest ground
        which was three pins over and the problem went away.

        I think mounting the ESP32-CAM on a good board with a ground plane along with bypassing the 3.3V pin may help those who are having issues running off 3.3V.

        Best Regards,

        Bob

        Reply
  23. The code works great 🙂 I have my ESP32 setup as an Access Point.
    My issue is when I have my smart phone or pc connected and then leave the house and come back and reconnect to my ESP, the webpage will not refresh unless I reset the ESP and reconnect

    Reply

Leave a Reply to Col Cancel reply

Download our Free eBooks and Resources

Get instant access to our FREE eBooks, Resources, and Exclusive Electronics Projects by entering your email address below.